;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; ED
;;
;; Editing a macro on-the-fly. Brilliant.
;; Usage: /ed <macro name>

/def ed = /let testStr $(/list %*)%;/let firstPos $[strchr({testStr}, "/")]%;/input $[substr({testStr},{firstPos})]


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; PERC
;;
;; Return percentual value of X from Y.
;; Usage: /perc X Y or $[perc(X,Y)]

/def perc = /return trunc(({1}*100.0)/{2})


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; ECHOVAR
;;
;; Show a boolean as "ON/OFF" instead of "0/1"
;; Usage: /echovar <variable>

/def echoVar = /eval /echo -p $[pad(strcat(toupper(substr(%1, 0, 1)), substr(%1, 1)),-15)] $[test(%1) ? "@{BCgreen}ON" : "@{BCred}OFF"]@{n}


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; DROPINFORM
;;
;; Usage: /dropInform <effect length (s)> <warning marginal (s)> <effect name>
;; E.g. /dropInform 35 5 Some annoying vuln

/def dropInform = /repeat -$[{1}-{2}] 1 /echo -aBCred %-2 is dropping in %{2} seconds!


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; ECHODIFF
;;
;; Echo the given value if it's not 0 (green if >0, red if <0)
;; NOTE! Use /echo -p with this.
;; Usage: /echoDiff X or $[echoDiff(X)]

/def echoDiff = /let testNum %1%;/result strcat((test(testNum!=0) ? strcat((test(testNum<0) ? "(@{BCred}" : "(@{BCgreen}"),%testNum,"@{n})") : ""))


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; ECHOTIME
;;
;; Show seconds in more comprehensive form
;; Usage: /echoTime X or $[echoTime(X)]

/def echoTime = /result strcat((test(trunc(%*/60)) ? strcat(trunc(%*/60),"min ") : ""),(test(mod(%*,60)) ? strcat(mod(%*,60),"s") : ""))


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; CAPITALIZE
;;
;; Capitalize the first letter of given string.
;; Usage: /capitalize X or $[capitalize("X")]

/def capitalize = /let tempStr %*%;/result toupper(tempStr, 1)


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; ECHO_MISC
;;
;; Used in a couple of my trigs.
;; Usage: /echo_misc <colour> <title> <message>

/def echo_misc = /echo -p @{BC%1}[ $[toupper(%2)] ]@{n} @{B}%-2@{n}